[Tex/LaTex] Emacs + SyncTex + Evince

emacsevince

I am trying to setup forward search and inverse search between Emacs 24.3.1 and Auctex under Ubuntu 14.04.

Forward search is working fine by enable TeX-source-correlate-mode in Emacs but while performing this search, the focus also moves to PDF. I would like to keep the focus on .tex file during forward search. Is there any hack or command available to achieve this.

I would also like to setup inverse-search. I have tried Ctrl + left click but it doesn't work.

Best Answer

You need to (i) tell Emacs what is your document viewer, and then (ii) configure the document viewer to collaborate with Emacs to use the inverse search, that is, Ctrl+left click.

I don't think that Evince offers configuration option directly. I prefer more to work with Okular than Evince. The following post describes how to activate the forwards and reverse search on Auctex+Okular. I hope that you find it helpful: How to configure Emacs and AUCTeX to perform Forward and Inverse Search

Related Solutions

[Tex/LaTex] Setup SyncTeX with Emacs

I combined some of the links mentioned here, you will find the links in the source comments. This code supports:

Forward search (Emacs to Evince, via C-c C-v)
Backward/Inverse search (Evince to Emacs, via C-Mouse-1, that is Ctrl + "Left Click" in Evince)
Path names with spaces
Multifile setups (TeX files requested by Evince will be opened if they aren't open yet)

; SyncTeX basics

; un-urlify and urlify-escape-only should be improved to handle all special characters, not only spaces.
; The fix for spaces is based on the first comment on http://emacswiki.org/emacs/AUCTeX#toc20

(defun un-urlify (fname-or-url)
  "Transform file:///absolute/path from Gnome into /absolute/path with very limited support for special characters"
  (if (string= (substring fname-or-url 0 8) "file:///")
      (url-unhex-string (substring fname-or-url 7))
    fname-or-url))

(defun urlify-escape-only (path)
  "Handle special characters for urlify"
  (replace-regexp-in-string " " "%20" path))

(defun urlify (absolute-path)
  "Transform /absolute/path to file:///absolute/path for Gnome with very limited support for special characters"
  (if (string= (substring absolute-path 0 1) "/")
      (concat "file://" (urlify-escape-only absolute-path))
      absolute-path))


; SyncTeX backward search - based on http://emacswiki.org/emacs/AUCTeX#toc20, reproduced on https://tex.stackexchange.com/a/49840/21017

(defun th-evince-sync (file linecol &rest ignored)
  (let* ((fname (un-urlify file))
         (buf (find-file fname))
         (line (car linecol))
         (col (cadr linecol)))
    (if (null buf)
        (message "[Synctex]: Could not open %s" fname)
      (switch-to-buffer buf)
      (goto-line (car linecol))
      (unless (= col -1)
        (move-to-column col)))))

(defvar *dbus-evince-signal* nil)

(defun enable-evince-sync ()
  (require 'dbus)
  ; cl is required for setf, taken from: http://lists.gnu.org/archive/html/emacs-orgmode/2009-11/msg01049.html
  (require 'cl)
  (when (and
         (eq window-system 'x)
         (fboundp 'dbus-register-signal))
    (unless *dbus-evince-signal*
      (setf *dbus-evince-signal*
            (dbus-register-signal
             :session nil "/org/gnome/evince/Window/0"
             "org.gnome.evince.Window" "SyncSource"
             'th-evince-sync)))))

(add-hook 'LaTeX-mode-hook 'enable-evince-sync)


; SyncTeX forward search - based on https://tex.stackexchange.com/a/46157

;; universal time, need by evince
(defun utime ()
  (let ((high (nth 0 (current-time)))
        (low (nth 1 (current-time))))
   (+ (* high (lsh 1 16) ) low)))

;; Forward search.
;; Adapted from http://dud.inf.tu-dresden.de/~ben/evince_synctex.tar.gz
(defun auctex-evince-forward-sync (pdffile texfile line)
  (let ((dbus-name
     (dbus-call-method :session
               "org.gnome.evince.Daemon"  ; service
               "/org/gnome/evince/Daemon" ; path
               "org.gnome.evince.Daemon"  ; interface
               "FindDocument"
               (urlify pdffile)
               t     ; Open a new window if the file is not opened.
               )))
    (dbus-call-method :session
          dbus-name
          "/org/gnome/evince/Window/0"
          "org.gnome.evince.Window"
          "SyncView"
          (urlify-escape-only texfile)
          (list :struct :int32 line :int32 1)
  (utime))))

(defun auctex-evince-view ()
  (let ((pdf (file-truename (concat default-directory
                    (TeX-master-file (TeX-output-extension)))))
    (tex (buffer-file-name))
    (line (line-number-at-pos)))
    (auctex-evince-forward-sync pdf tex line)))

;; New view entry: Evince via D-bus.
(setq TeX-view-program-list '())
(add-to-list 'TeX-view-program-list
         '("EvinceDbus" auctex-evince-view))

;; Prepend Evince via D-bus to program selection list
;; overriding other settings for PDF viewing.
(setq TeX-view-program-selection '())
(add-to-list 'TeX-view-program-selection
         '(output-pdf "EvinceDbus"))

This will likely break for:

Path names with special characters other than spaces

I used these helpful links:

https://tex.stackexchange.com/a/46157 (forward search)
http://emacswiki.org/emacs/AUCTeX#toc20 (backward search, space handling)
http://lists.gnu.org/archive/html/emacs-orgmode/2009-11/msg01049.html (fix for missing setf)

I tested with

Emacs 24.2
Evince 3.4.0
OpenSUSE 12.2

[Tex/LaTex] Xdvi to Emacs inverse search not working in Emacs 24.3.1 / AucTeX-11.87 in Ubuntu 12.04

It's better to activate TeX-source-correlate-mode setting the option with the same name to non-nil.

Here is a working (for me) .emacs based on your:

(setq tex-dvi-view-command "xdvi -editor 'emacsclient -a emacs --no-wait +%l %f'")
(eval-after-load "tex"
  '(progn
     ;;update the dvi file after each successful compilation
     (add-to-list 'TeX-output-view-style
          '("^dvi$" "."
            "%(o?)xdvi -watchfile 1 %dS %d"))
     (setq TeX-source-correlate-start-server t
       TeX-auto-save t
       TeX-parse-self t
       reftex-plug-into-AUCTeX t
       ;; Activate TeX-source-correlate-mode
       TeX-source-specials-mode t
       ;; Inverse DVI Search
       TeX-source-correlate-method 'source-specials)
     (setq-default TeX-master nil)
     (add-hook 'LaTeX-mode-hook
           (lambda
         (visual-line-mode)
         (flyspell-mode)
         (LaTeX-math-mode)
         (turn-on-reftex)))))

Best Answer

Related Solutions

[Tex/LaTex] Setup SyncTeX with Emacs

[Tex/LaTex] Xdvi to Emacs inverse search not working in Emacs 24.3.1 / AucTeX-11.87 in Ubuntu 12.04

Related Question