[Tex/LaTex] Dissertation: How to customize *.bst

bibliographiesbibtex

I am almost finished with my PhD thesis (of course in TeX) 🙂 I was looking for hours for a nice bib style which fits the requirements of the Prof, then I looked into the *.bst which rather confused me. Unfortunately, I was not able to generate a bibliography, got me alot of errors. Anyway, the closest *.bst is cj.bst, but the YEAR should be in between the VOLUME and PAGES. Here is an example how it should look like:

Wester, H.J.; Herz, M.; Weber, W.; Heiss, P. Synthesis and
radiopharmacology of O-(2- [18F]fluoroethyl)-L-tyrosine for tumor imaging. J
Nucl Med 40 (1999) 205–212.

I really hope you can help me!

Best Answer

If you like bst hacking more than using a package like biblatex you may edit cj.bst. First add the date to FUNCTION {format.vol.num.pages}:

FUNCTION {format.vol.num.pages}
{ volume field.or.null
  duplicate$ empty$ 'skip$
    {
      "volume" bibinfo.check
    }
  if$
  bolden
  swap$
  date.block
  format.date "year" output.check
  format.journal.pages
}

then remove the date from FUNCTION {article}:

FUNCTION {article}
{ output.bibitem
  format.authors "author" output.check
  format.title "title" output.check
  new.sentence
  crossref missing$
    {
      journal
      "journal" bibinfo.check
      emphasize
      "journal" output.check
      format.vol.num.pages output
    }
    { format.article.crossref output.nonnull
      format.pages output
    }
  if$
  format.note output
  fin.entry
}

Additional changes to other entry types may be needed, depending on what you want. But if you really need several changes, I would recommend using biblatex.

Related Question