Hyper Elliptic Curve – Number of Rational Points Over Finite Field

Question

Let $C$ be a curve given by $y^5=-x^2+x$ defined over $\overline{\Bbb{F}_{11}}$.

I want to calculate　$\# C(\Bbb{F}_{11})$ and $\# C(\Bbb{F}_{11^2})$.

I calculated $\# C(\Bbb{F}_{11})＝\#\{(0,0),(1,0),(2,±3),(3,±4),(6,±5),(9, ±4),(10,±3),∞\}=13$(where $∞=(1:0:0)$ in projective closure) by my hand.

But I'm stuck with calculating $\# C(\Bbb{F}_{11^2})$.
Maybe there is no method (in other words, theoretical way) to calculate $\# C(\Bbb{F}_{11^2})$ by hand, but calculation with computer is also appreciated.

Background. If over $\Bbb{F}_p$ and $5$ does not divide $p-1$, $y \mapsto y^5$ is bijective, so the number of rational point is $p+1$. $p=5$ maybe(if my above counting is correct) a smallest example s.t. $p$ of $\# C(\Bbb{F}_p)\neq p+1$

Answer 1

The job is easily done with computer support, here sage. Let us do this first.

F = GF(11)
R.<x,y,z> = PolynomialRing(F)
C = Curve(y^5 + z^3*(x^2 - x*z))
print(f'C is the curve:\n{C}')

We have initialized:

C is the curve:
Projective Plane Curve over Finite Field of size 11
defined by y^5 + x^2*z^3 - x*z^4

Then in a dialog with the sage interpreter:

sage: C.is_singular()
True
sage: C.singular_points()
[(1 : 0 : 0)]

sage: C.L_polynomial()
121*t^4 + 11*t^3 - 9*t^2 + t + 1

sage: C.rational_points()
[(0 : 0 : 1),
 (1 : 0 : 0),
 (1 : 0 : 1),
 (4 : 2 : 1),
 (4 : 6 : 1),
 (4 : 7 : 1),
 (4 : 8 : 1),
 (4 : 10 : 1),
 (8 : 2 : 1),
 (8 : 6 : 1),
 (8 : 7 : 1),
 (8 : 8 : 1),
 (8 : 10 : 1)]
sage: len(C.rational_points())
13

To see how many points there are after a quadratic extension...

sage: len(C.base_extend(GF(11^2)).rational_points())
103

---

So the zeta function of $C$ is $$ \begin{aligned} Z(C,T) &=\exp\left(\sum_k\frac 1k\cdot\#C(\Bbb F_{11^k})\cdot T^k\right) \\ &=\frac{L(T)}{(1-T)(1-11T)} \\ &=\frac{1+T-9T^2+11T^3+121T^4}{(1-T)(1-11T)} \ , \end{aligned} $$ and sage gave the above L_polynomial for C, so we can extract the cardinalities $\# C(\Bbb F_{11^k})$ for some first $k$ values:

sage: R.<T> = PowerSeriesRing(QQ)
....: log( C.L_polynomial()(T) / (1 - T) / (1 - 11*T) ) + O(T^8)
13*T + 103/2*T^2 + 1393/3*T^3 + 14883/4*T^4 + 161448/5*T^5 + 1774963/6*T^6 + 19477303/7*T^7 + O(T^8)

So we expect for instance $1393$ points in an extension of degree three of $F$... and indeed, after a long time to compute the enumeration...

sage: len(C.base_extend(GF(11^3)).rational_points())
1393

---

To do something with bare hands, let us analyze the map $y\to y^5$ on $F=\Bbb F_{11}$ and on $L=\Bbb F_{121}$. Zero is mapped to zero. Else, for $y\ne 0$? We have $y^{10}=1$ on $F$. So $y^5$ is $\pm 1$ for $y\in F$, and each value is taken five times.

The listed points above show that we can realize only $y^5=-1$ (with $y\ne 0$). Observe that if $(x,y)$ satisfies $$ y^5 =x(1-x)\ , $$ then this also holds for $(y,1-x)$. (So if we know the five points $(4,y)$, then we also know the other five point $(1-4,y)=(8,y)$.)

Also, $(x,y)$ point on $C$ immediately gives the points $(x,g^2y)$, $(x,g^4y)$, $(x,g^4y)$, $(x,g^8y)$, where $g$ is a multiplicative generator of $F^\times$. And if $x$ in $F$ or $L$ is a first component of a point, than there are exactly five points of the shape $(x,g^{2k}y)$ having this first component.

sage: F
Finite Field of size 11
sage: g = F.multiplicative_generator()
sage: g
2
sage: [g^(2*k) for k in [0..4]]
[1, 4, 5, 9, 3]

One can also write $x^2-x=x^2-12x=(x-6)^2-36=(x-6)^2-3$. Combining the above arguments, the list of points offered by sage above over $F=\Bbb F_{11}$ can be also easily computed with bare hands.

---

What above $L$, the field with $121$ elements? We restrict to finding affine $L$-rational points $(x,y)$ which are not defined over $F$. As seen above, it is enough to find the $x$-values having $x(1-x)$ a fifth power.

Again, with the computer:

sage: F = GF(11)
sage: RF.<U> = PolynomialRing(F)
sage: L.<a> = GF(11^2, U^2 + U + 1)
sage: L
Finite Field in a of size 11^2
sage: a.minpoly()
x^2 + x + 1

sage: list(set([x for x in L if (U^5 - x*(1-x)).roots(ring=L)]))
[0,
 1,
 4,
 8,
 a + 1,
 a + 3,
 a + 10,
 2*a + 1,
 2*a + 2,
 4*a + 1,
 4*a + 4,
 5*a + 7,
 5*a + 10,
 6*a + 2,
 6*a + 5,
 7*a,
 7*a + 8,
 9*a,
 9*a + 10,
 10*a,
 10*a + 2,
 10*a + 9]
sage: 

For the first $x$-values $0,1,4,8$ we know the resulting $13$ $F$-rational points. The next $18$ values of $x$ (which are $9$ pairs of values $x, 1-x$) introduce further $18\cdot 5=90$ rational points. This gives a total of $13+90=103$ points.

---

Is there any chance to proceed in a structural manner? We already know that the $L$-polynomial is of the shape $$ L(T)=1 + T + cT^2 + 11T^3 + 121T^4\ . $$ We have reasons to expect $\# C(\Bbb F_{121})=13 + 2\cdot 5\cdot k$ for some integer $k$. (Using $x\to 1-x$, and $y\to g^{2k}y$.) Also there are bounds for this number: $$ -2\cdot2\cdot\sqrt{121}\le 121+1\le 2\cdot2\cdot\sqrt{121}\ . $$ So only $83$, $93$, $103$, $113$, $123$, $133$, $143$, $153$, $163$ can show up. One can now compute the corresponding $c$-values in the $L$-polynomial, and check if the roots have all the right modulus... (But again, doing so i need a computer.)

---

---

Later EDIT: "Same question" for the hyperelliptic curve in next genus, $$ C \ :\qquad y^7 = -x^2 + x\ , $$ over the fiels with $p$ and $p^2$ elements, $p$ being the prime $p=29$.

p = 29
F = GF(p)
F2 = GF(p^2)

R.<x,y,z> = PolynomialRing(F)
RQ.<T> = PowerSeriesRing(QQ)

C = Curve(y^7 + z^5*(x^2 - x*z))

L = C.L_polynomial()
Z = log( L(T) / (1 - T) / (1 - p*T) )

print(f"F is the field:\n{F}\n")
print(f"F2 is the field:\n{F2}\n")
print(f"C is the curve:\n{C}\n")
print(f"The L-Polynomial of C is:\n{L}\n")
print(f"The Z-function of C is:\n{Z}\n")
print(f"Check for the cardinalities C(F) and C(F2):")
print(f"# C(F)  = {len(C.rational_points())}")
print(f"# C(F2) = {len(C.base_extend(F2).rational_points())}")

Results (with manually slightly rearranged output to fit in the MSE band width) after some few minutes:

F is the field:
Finite Field of size 29

F2 is the field:
Finite Field in z2 of size 29^2

C is the curve:
Projective Plane Curve over Finite Field of size 29 
defined by y^7 + x^2*z^5 - x*z^6

The L-Polynomial of C is:
24389*t^6 + 841*t^5 - 783*t^4 - 69*t^3 - 27*t^2 + t + 1

The Z-function of C is:
31*T + 787/2*T^2 + 24265/3*T^3 + 702859/4*T^4 + 20513391/5*T^5 
    + 594795463/6*T^6 + 17249583480/7*T^7 + 500244091539/8*T^8
    + 14507146991683/9*T^9 + 420707233574967/10*T^10 
    + 12200509372167609/11*T^11 + 353814782784565987/12*T^12 
    + 10260628712662461255/13*T^13 + 148779116346777556246/7*T^14
    + 575279249814016300549*T^15 
    + 250246473681188954827203/16*T^16 
    + 7257147736729702375185933/17*T^17
    + 210457284365192863709980951/18*T^18
    + 6103261246589707340158433551/19*T^19 + O(T^20)

Check for the cardinalities C(F) and C(F2):
# C(F)  = 31
# C(F2) = 787

---

Later EDIT #2: And the same code as above, with the following two lines changed, so that we are working with $C$ with affine equation $y^5 =-x^2+x$ in characteristic $p=31$,

p = 31
C = Curve(y^5 + z^3*(x^2 - x*z))

has the results (also manually changed):

F is the field:
Finite Field of size 31

F2 is the field:
Finite Field in z2 of size 31^2

C is the curve:
Projective Plane Curve over Finite Field of size 31 
defined by y^5 + x^2*z^3 - x*z^4

The L-Polynomial of C is:
961*t^4 + 341*t^3 + 61*t^2 + 11*t + 1

The Z-function of C is:
43*T + 963/2*T^2 + 30133/3*T^3 + 919803/4*T^4 + 28638348/5*T^5 
 + 295837381/2*T^6 + 27512900563/7*T^7 
 + 852887808483/8*T^8 + 26439628483153/9*T^9
 + 409814154294599/5*T^10 + 25408477098836743/11*T^11
 + 262554260396916721/4*T^12 + 24417546300228124333/13*T^13
 + 756943935258853246503/14*T^14 + 7821753997315868117516/5*T^15
 + 727423121745279143223843/16*T^16
 + 22550116774161780528174763/17*T^17
 + 233017873333033411054492561/6*T^18
 + 21670662219970398858049959853/19*T^19 + O(T^20)

Check for the cardinalities C(F) and C(F2):
# C(F)  = 43
# C(F2) = 963

---

Later EDIT #3: As asked in the comments, let $C$ be the curve with affine equation $y^5 =-x^2+x$, we cover all characteristics $p$ up to $p=41$, plot in each case the $L$-polynomial $L_p(T)$, and the first terms in the congruent / congruence zeta function $Z_p(T)=Z(C/\Bbb F_p, T)$ modulo $O(T^6)$. The included information in the following mathjax / latex aligned block was produced by sage, the code is postponed: $$ \begin{aligned} L_{2}(T) &= 1 + 4 T^{4}\\ \log Z_{2}(T) &= 3 T + \frac{5}{2} T^{2} + 3 T^{3} + \frac{33}{4} T^{4} + \frac{33}{5} T^{5} + O(T^{6})\\[2mm] L_{3}(T) &= 1 + 9 T^{4}\\ \log Z_{3}(T) &= 4 T + 5 T^{2} + \frac{28}{3} T^{3} + \frac{59}{2} T^{4} + \frac{244}{5} T^{5} + O(T^{6})\\[2mm] L_{5}(T) &= 1\\ \log Z_{5}(T) &= 6 T + 13 T^{2} + 42 T^{3} + \frac{313}{2} T^{4} + \frac{3126}{5} T^{5} + O(T^{6})\\[2mm] L_{7}(T) &= 1 + 49 T^{4}\\ \log Z_{7}(T) &= 8 T + 25 T^{2} + \frac{344}{3} T^{3} + \frac{1299}{2} T^{4} + \frac{16808}{5} T^{5} + O(T^{6})\\[2mm] L_{11}(T) &= 1 + T - 9 T^{2} + 11 T^{3} + 121 T^{4}\\ \log Z_{11}(T) &= 13 T + \frac{103}{2} T^{2} + \frac{1393}{3} T^{3} + \frac{14883}{4} T^{4} + \frac{161448}{5} T^{5} + O(T^{6})\\[2mm] L_{13}(T) &= 1 + 169 T^{4}\\ \log Z_{13}(T) &= 14 T + 85 T^{2} + \frac{2198}{3} T^{3} + \frac{14619}{2} T^{4} + \frac{371294}{5} T^{5} + O(T^{6})\\[2mm] L_{17}(T) &= 1 + 289 T^{4}\\ \log Z_{17}(T) &= 18 T + 145 T^{2} + 1638 T^{3} + \frac{42339}{2} T^{4} + \frac{1419858}{5} T^{5} + O(T^{6})\\[2mm] L_{19}(T) &= 1 + 38 T^{2} + 361 T^{4}\\ \log Z_{19}(T) &= 20 T + 219 T^{2} + \frac{6860}{3} T^{3} + \frac{64439}{2} T^{4} + 495220 T^{5} + O(T^{6})\\[2mm] L_{23}(T) &= 1 + 529 T^{4}\\ \log Z_{23}(T) &= 24 T + 265 T^{2} + 4056 T^{3} + \frac{140979}{2} T^{4} + \frac{6436344}{5} T^{5} + O(T^{6})\\[2mm] L_{29}(T) &= 1 + 58 T^{2} + 841 T^{4}\\ \log Z_{29}(T) &= 30 T + 479 T^{2} + 8130 T^{3} + \frac{351959}{2} T^{4} + 4102230 T^{5} + O(T^{6})\\[2mm] L_{31}(T) &= 1 + 11 T + 61 T^{2} + 341 T^{3} + 961 T^{4}\\ \log Z_{31}(T) &= 43 T + \frac{963}{2} T^{2} + \frac{30133}{3} T^{3} + \frac{919803}{4} T^{4} + \frac{28638348}{5} T^{5} + O(T^{6})\\[2mm] L_{37}(T) &= 1 + 1369 T^{4}\\ \log Z_{37}(T) &= 38 T + 685 T^{2} + \frac{50654}{3} T^{3} + \frac{939819}{2} T^{4} + \frac{69343958}{5} T^{5} + O(T^{6})\\[2mm] L_{41}(T) &= 1 - 9 T + 71 T^{2} - 369 T^{3} + 1681 T^{4}\\ \log Z_{41}(T) &= 33 T + \frac{1743}{2} T^{2} + 23001 T^{3} + \frac{2825563}{4} T^{4} + \frac{115886298}{5} T^{5} + O(T^{6})\\[2mm] \end{aligned} $$ Used code:

RT.<T> = PowerSeriesRing(QQ, default_prec=6)
for p in primes(42):
    R.<x,y,z> = PolynomialRing(GF(p))
    C = Curve(y^5 + z^3*(x^2 - x*z))    # automatically over GF(p)
    L = C.L_polynomial()
    Z = L(T) / (1 - T) / (1 - p*T)
    print(f"L_{{{p}}}(T) &= {latex(L(T))}\\\\")
    print(f"\\log Z_{{{p}}}(T) &= {latex(log(Z))}\\\\[2mm]")

---

Later EDIT #4: As asked in the comments, let us also cover experimentally the curve $C$ with affine equation $y^2 =(x^2+1)(x^4 - 8x^3 + 2x^2 +8x + 1)$ for some small characteristics. Same code, only the curve is changed. We have a singular curve, so that we do not expect to see an $L$-polynomial of degree equal to doubled genus. $$ \begin{aligned} p &= 3\text{ , genus = 0, singular}\\ L_{3}(t) &= 1 - t + t^{2} - t^{3} = \left(-1\right) \cdot (-1 + t) \cdot (1 + t^{2})\\ \log Z_{3}(T) &= 3 T + \frac{11}{2} T^{2} + 9 T^{3} + \frac{79}{4} T^{4} + \frac{243}{5} T^{5} + O(T^{6})\\[2mm] p &= 5\text{ , genus = 2, singular}\\ L_{5}(t) &= 1 - t - 6 t^{2} + 6 t^{3} + 25 t^{4} - 25 t^{5} = \left(-1\right) \cdot (-1 + t) \cdot (1 - 4 t + 5 t^{2}) \cdot (1 + 4 t + 5 t^{2})\\ \log Z_{5}(T) &= 5 T + \frac{13}{2} T^{2} + \frac{125}{3} T^{3} + \frac{653}{4} T^{4} + 625 T^{5} + O(T^{6})\\[2mm] p &= 7\text{ , genus = 2, singular}\\ L_{7}(t) &= 1 + 7 t + 22 t^{2} + 26 t^{3} - 7 t^{4} - 49 t^{5} = \left(-1\right) \cdot (-1 + t) \cdot (1 + 4 t + 7 t^{2})^{2}\\ \log Z_{7}(T) &= 15 T + \frac{45}{2} T^{2} + 101 T^{3} + \frac{2589}{4} T^{4} + 3267 T^{5} + O(T^{6})\\[2mm] p &= 11\text{ , genus = 2, singular}\\ L_{11}(t) &= 1 - t - 6 t^{2} + 6 t^{3} + 121 t^{4} - 121 t^{5} = \left(-1\right) \cdot (-1 + t) \cdot (1 - 6 t^{2} + 121 t^{4})\\ \log Z_{11}(T) &= 11 T + \frac{109}{2} T^{2} + \frac{1331}{3} T^{3} + \frac{15053}{4} T^{4} + \frac{161051}{5} T^{5} + O(T^{6})\\[2mm] p &= 13\text{ , genus = 2, singular}\\ L_{13}(t) &= 1 - t - 22 t^{2} + 22 t^{3} + 169 t^{4} - 169 t^{5} = \left(-1\right) \cdot (-1 + t) \cdot (1 - 22 t^{2} + 169 t^{4})\\ \log Z_{13}(T) &= 13 T + \frac{125}{2} T^{2} + \frac{2197}{3} T^{3} + \frac{28269}{4} T^{4} + \frac{371293}{5} T^{5} + O(T^{6})\\[2mm] p &= 17\text{ , genus = 2, singular}\\ L_{17}(t) &= 1 + 11 t + 58 t^{2} + 134 t^{3} + 85 t^{4} - 289 t^{5} = \left(-1\right) \cdot (-1 + t) \cdot (1 + 6 t + 17 t^{2})^{2}\\ \log Z_{17}(T) &= 29 T + \frac{285}{2} T^{2} + \frac{4733}{3} T^{3} + \frac{84669}{4} T^{4} + \frac{1416029}{5} T^{5} + O(T^{6})\\[2mm] p &= 19\text{ , genus = 2, singular}\\ L_{19}(t) &= 1 - t - 22 t^{2} + 22 t^{3} + 361 t^{4} - 361 t^{5} = \left(-1\right) \cdot (-1 + t) \cdot (1 - 22 t^{2} + 361 t^{4})\\ \log Z_{19}(T) &= 19 T + \frac{317}{2} T^{2} + \frac{6859}{3} T^{3} + \frac{130797}{4} T^{4} + \frac{2476099}{5} T^{5} + O(T^{6})\\[2mm] p &= 23\text{ , genus = 2, singular}\\ L_{23}(t) &= 1 - t + 46 t^{2} - 46 t^{3} + 529 t^{4} - 529 t^{5} = \left(-1\right) \cdot (-1 + t) \cdot (1 + 23 t^{2})^{2}\\ \log Z_{23}(T) &= 23 T + \frac{621}{2} T^{2} + \frac{12167}{3} T^{3} + \frac{277725}{4} T^{4} + \frac{6436343}{5} T^{5} + O(T^{6})\\[2mm] p &= 29\text{ , genus = 2, singular}\\ L_{29}(t) &= 1 - t - 54 t^{2} + 54 t^{3} + 841 t^{4} - 841 t^{5} = \left(-1\right) \cdot (-1 + t) \cdot (1 - 54 t^{2} + 841 t^{4})\\ \log Z_{29}(T) &= 29 T + \frac{733}{2} T^{2} + \frac{24389}{3} T^{3} + \frac{704813}{4} T^{4} + \frac{20511149}{5} T^{5} + O(T^{6})\\[2mm] p &= 31\text{ , genus = 2, singular}\\ L_{31}(t) &= 1 + 7 t + 70 t^{2} + 170 t^{3} + 713 t^{4} - 961 t^{5} = \left(-1\right) \cdot (-1 + t) \cdot (1 + 4 t + 31 t^{2})^{2}\\ \log Z_{31}(T) &= 39 T + \frac{1053}{2} T^{2} + 9725 T^{3} + \frac{923133}{4} T^{4} + \frac{28649799}{5} T^{5} + O(T^{6})\\[2mm] p &= 37\text{ , genus = 2, singular}\\ L_{37}(t) &= 1 - t - 70 t^{2} + 70 t^{3} + 1369 t^{4} - 1369 t^{5} = \left(-1\right) \cdot (-1 + t) \cdot (1 - 12 t + 37 t^{2}) \cdot (1 + 12 t + 37 t^{2})\\ \log Z_{37}(T) &= 37 T + \frac{1229}{2} T^{2} + \frac{50653}{3} T^{3} + \frac{1869837}{4} T^{4} + \frac{69343957}{5} T^{5} + O(T^{6})\\[2mm] p &= 41\text{ , genus = 2, singular}\\ L_{41}(t) &= 1 + 3 t + 82 t^{2} + 78 t^{3} + 1517 t^{4} - 1681 t^{5} = \left(-1\right) \cdot (-1 + t) \cdot (1 + 2 t + 41 t^{2})^{2}\\ \log Z_{41}(T) &= 45 T + \frac{1837}{2} T^{2} + 22815 T^{3} + \frac{2820317}{4} T^{4} + 23177321 T^{5} + O(T^{6})\\[2mm] p &= 43\text{ , genus = 2, singular}\\ L_{43}(t) &= 1 - t - 70 t^{2} + 70 t^{3} + 1849 t^{4} - 1849 t^{5} = \left(-1\right) \cdot (-1 + t) \cdot (1 - 70 t^{2} + 1849 t^{4})\\ \log Z_{43}(T) &= 43 T + \frac{1709}{2} T^{2} + \frac{79507}{3} T^{3} + \frac{3416397}{4} T^{4} + \frac{147008443}{5} T^{5} + O(T^{6})\\[2mm] p &= 47\text{ , genus = 2, singular}\\ L_{47}(t) &= 1 + 15 t + 142 t^{2} + 594 t^{3} + 1457 t^{4} - 2209 t^{5} = \left(-1\right) \cdot (-1 + t) \cdot (1 + 8 t + 47 t^{2})^{2}\\ \log Z_{47}(T) &= 63 T + \frac{2269}{2} T^{2} + 34197 T^{3} + \frac{4886717}{4} T^{4} + \frac{229346623}{5} T^{5} + O(T^{6})\\[2mm] p &= 53\text{ , genus = 2, singular}\\ L_{53}(t) &= 1 - t - 6 t^{2} + 6 t^{3} + 2809 t^{4} - 2809 t^{5} = \left(-1\right) \cdot (-1 + t) \cdot (1 - 6 t^{2} + 2809 t^{4})\\ \log Z_{53}(T) &= 53 T + \frac{2797}{2} T^{2} + \frac{148877}{3} T^{3} + \frac{7901645}{4} T^{4} + \frac{418195493}{5} T^{5} + O(T^{6})\\[2mm] p &= 59\text{ , genus = 2, singular}\\ L_{59}(t) &= 1 - t - 102 t^{2} + 102 t^{3} + 3481 t^{4} - 3481 t^{5} = \left(-1\right) \cdot (-1 + t) \cdot (1 - 102 t^{2} + 3481 t^{4})\\ \log Z_{59}(T) &= 59 T + \frac{3277}{2} T^{2} + \frac{205379}{3} T^{3} + \frac{12110477}{4} T^{4} + \frac{714924299}{5} T^{5} + O(T^{6})\\[2mm] p &= 61\text{ , genus = 2, singular}\\ L_{61}(t) &= 1 - t - 86 t^{2} + 86 t^{3} + 3721 t^{4} - 3721 t^{5} = \left(-1\right) \cdot (-1 + t) \cdot (1 - 86 t^{2} + 3721 t^{4})\\ \log Z_{61}(T) &= 61 T + \frac{3549}{2} T^{2} + \frac{226981}{3} T^{3} + \frac{13845933}{4} T^{4} + \frac{844596301}{5} T^{5} + O(T^{6})\\[2mm] p &= 67\text{ , genus = 2, singular}\\ L_{67}(t) &= 1 - t - 118 t^{2} + 118 t^{3} + 4489 t^{4} - 4489 t^{5} = \left(-1\right) \cdot (-1 + t) \cdot (1 - 118 t^{2} + 4489 t^{4})\\ \log Z_{67}(T) &= 67 T + \frac{4253}{2} T^{2} + \frac{300763}{3} T^{3} + \frac{20141229}{4} T^{4} + \frac{1350125107}{5} T^{5} + O(T^{6})\\[2mm] \end{aligned} $$

PSR.<T> = PowerSeriesRing(QQ, default_prec=6)
RQ.<t,u> = PolynomialRing(QQ, order='neglex')
for p in primes(3, 70):
    R.<x,y> = PolynomialRing(GF(p))
    Ca = Curve( -y^2 + (x^2 + 1)*(x^4 - 8*x^3 + 2*x^2 + 8*x + 1) )
    C = Ca.projective_closure()    # Ca is affine, C projective.
    L = C.L_polynomial()
    Z = L(T) / (1 - T) / (1 - p*T)
    print(f"p &= {p}\\text{{ , genus = {C.genus()}{', singular' if C.is_singular() else ''}}}\\\\")
    print(f"L_{{{p}}}(t) &= {latex(L(t))} = {latex(L(t).factor())}\\\\")
    print(f"\\log Z_{{{p}}}(T) &= {latex(log(Z))}\\\\[2mm]")