[Math] The vertices of an equilateral triangle are shrinking towards each other

analytic geometrygeometryphysics

For an equilateral triangle ABC of side $a$ vertex A is always moving in the direction of vertex B, which is always moving the direction of vertex C, which is always moving in the direction of vertex A. The modulus of their "velocity" is a constant. When and where do they converge.

Attempt. Found the "when" using a physics style approach by "fixing the frame" on one of the vertices. (From this frame, other two vertex are moving towards origin in a straight line and components of their speed along this line can be used to find when the three meet at origin) For the "where" it is difficult using above approach as this is some kind of rotating and shrinking triangle which is difficult to translate.

@all Apologies for bumping this question. I wished to give an answer the bounty but it wont let me until the next 23 hours. For the record: I am not seeking new answers.

Update: A cool example of PSTricks package of $\LaTeX$, for anyone who finds this question later.

enter image description here

Link to code (a .tex file)

And using Pgf/TikZ

enter image description here

Source Page

Best Answer

Here's an animation showing the shrinking triangle:

Shrinking Triangle

As is required by the statement of the problem, the sides of the triangle are everywhere tangent to the blue curves.

The blue curves are logarithmic spirals. The curve on the right has endpoints $(0,0)$ and $(1,0)$, and is defined by the equation $$ r \;=\; \exp\left(-\sqrt{3}\;\theta\right). $$ Note that the triangle actually undergoes an infinite number of rotations as it shrinks towards the origin.

The rate at which the sides of the triangle shrink is equal to 3/2 of the speed at which the points move. (This follows from the fact that one endpoint of each edge has velocity tangent to the edge, while the other has a velocity component of $\sin(30^\circ)=1/2$ in the direction of the edge.) As a consequence, the length of each blue curve is $2/3$ of the side length of the large triangle.

Edit: Here is the Mathematica code for the animation above:

PolarToRectangular[{r_, theta_}] := {r*Cos[theta], r*Sin[theta]}
tmax = 2/Sqrt[3];
PolarCurve[t_] := {1 - t/tmax, -Log[1 - t/tmax]/Sqrt[3]}
f1[t_] := PolarToRectangular[PolarCurve[t]]
f2[t_] := PolarToRectangular[PolarCurve[t] + {0, 2 Pi/3}]
f3[t_] := PolarToRectangular[PolarCurve[t] + {0, 4 Pi/3}]
spirals = ParametricPlot[{f1[t], f2[t], f3[t]}, {t, 0, tmax},
    Axes -> None, ImageSize -> 300, PlotStyle -> Darker[Blue],
    PlotRange -> {{-0.7, 1.1}, {-0.9, 0.9}}];
triangle[t_] := Graphics[{Opacity[0], EdgeForm[Black],
    Polygon[{f1[t], f2[t], f3[t]}]}]
points[t_] := Graphics[{PointSize[Large], Point/@{f1[t],f2[t],f3[t]} }]
dt = tmax/75;
myframes = Table[Show[spirals, triangle[t], points[t]], {t, 0, 75*dt, dt}];
Export["ShrinkingTriangle.gif", myframes, 
    "DisplayDurations" -> {1}~Join~ConstantArray[0.04, 74]~Join~{1}]

This code exports the animation as a GIF. If you want to see the animation from within Mathematica, the last command would be ListAnimate[myframes] instead.

Related Question