Geometry – How to Find the Center of an Ellipse

conic sectionsgeometry

I have the following data:-

  • I have two points ($P_1$, $P_2$) that lie somewhere on the ellipse's circumference.
  • I know the angle ($\alpha$) that the major-axis subtends on x-axis.
  • I have both the radii ($a$ and $b$) of the ellipse.

I now need to find the center of this ellipse. It is known that we can get two possible ellipses using the above data.

I have tried solving this myself but the equation becomes so complex that I always give up.

This is what I have done till now:-

I took the normal ellipse equation $x^2/a^2 + y^2/b^2 = 1$. To compensate for the rotation and translation, I replaced $x$ and $y$ by $x\cos\alpha+y\sin\alpha-h$ and $-x\sin\alpha+y\cos\alpha-k$, respectively. $h$ and $k$ are x and y location of the ellipse's center.

Using these information I ended up with the following eq:-
$$a B_1\pm\sqrt{a^2 B_1^2 – C_1(b^2 h^2 – 2 A_1 b^2 h)} = a B_2\pm\sqrt{a^2 B_2^2 – C_2 (b^2 h^2 – 2 A_2 b^2 h)} \quad (1)$$

where $A = x\cos\alpha +y\sin\alpha$, $B = -x\sin\alpha+y\cos\alpha$ and $C = a^2 B^2 + A^2 b^2 – a^2 b^2$.

Now the only thing I need to get is $h$ from (1). All other values are known, but I am not able to single that out.

Anyway if the above equations looks insane then please solve it yourself, your way. I could have drifted into some very complicated path.

Best Answer

Let the points be $P_1(x_1, y_1)$ and $P_2(x_2, y_2)$, assumed to lie on an ellipse of semiaxes $a$ and $b$ with the $a$ axis making angle $\alpha$ to the $x$ axis.

Ellipse

Following @joriki, we rotate the points $P_i$ by $-\alpha$ into points

$$Q_i(x_i \cos(\alpha) + y_i \sin(\alpha), y_i \cos(\alpha) - x_i \sin(\alpha)).$$

We then rescale them by $(1/a, 1/b)$ to the points

$$R_i(\frac{x_i \cos(\alpha) + y_i \sin(\alpha)}{a}, \frac{y_i \cos(\alpha) - x_i \sin(\alpha)}{b}).$$

Circle

These operations convert the ellipse into a unit circle and the points form a chord of that circle. Let us now translate the midpoint of the chord to the origin: this is done by subtracting $(R_1 + R_2)/2$ (shown as $M$ in the figure) from each of $R_i$, giving points

$$S_1 = (R_1 - R_2)/2, \quad S_2 = (R_2 - R_1)/2 = -S_1$$

each of length $c$. Half the length of that chord is

$$c = ||(R_1 - R_2)||/2 = ||S_1|| = ||S_2||,$$

which by assumption lies between $0$ and $1$ inclusive. Set

$$s = \sqrt{1-c^2}.$$

The origin of the circle is found by rotating either of the $S_i$ by 90 degrees (in either direction) and rescaling by $s/c$, giving up to two valid solutions $O_1$ and $O_2$. (Rotation of a point $(u,v)$ by 90 degrees sends it either to $(-v,u)$ or $(v,-u)$.) For example, in the preceding figure it is evident that rotation $R_1$ by -90 degrees around $M$ and scaling it by $s/c$ will make it coincide with the circle's center. Reflecting the center about $M$ (which gives $2M$) produces the other possible solution.

Unwinding all this requires us to do the following to the $O_i$:

  • Translate by $(R_1+R_2)/2$,
  • Scale by $(a,b)$, and
  • Rotate by $\alpha$.

The cases $c \gt 1$, $c = 1$, and $c=0$ have to be treated specially. The first gives no solution, the second a unique solution, and the third infinitely many.

FWIW, here's a Mathematica 7 function. The arguments p1 and p2 are length-2 lists of numbers (i.e., point coordinates) and the other arguments are numbers. It returns a list of the possible centers (or Null if there are infinitely many).

f[\[Alpha]_, a_, b_, p1_, p2_] := Module[
   {
    r, s, q1, q2, m, t, \[Gamma], u, r1, r2, x, v
    },
   (* Rotate to align the major axis with the x-axis. *)
   r = RotationTransform[-\[Alpha]];
   (* Rescale the ellipse to a unit circle. *)
   s = ScalingTransform[{1/a, 1/b}];
   {q1, q2} = s[r[#]] & /@ {p1, p2};
   (* Compute the half-length of the chord. *)
   \[Gamma] = Norm[q2 - q1]/2;
   (* Take care of special cases. *)
   If[\[Gamma] > 1, Return[{}]];
   If[\[Gamma] == 0, Return[Null]];
   If[\[Gamma] == 1, 
    Return[{InverseFunction[Composition[s, r]][(q1 + q2)/2]}]];
   (* Place the origin between the two points. *)
   t = TranslationTransform[-(q1 + q2)/2];
   (* This ends the transformations.  
   The next steps find the centers. *)
   (* Rotate the points 90 degrees. *)
   u = RotationTransform [\[Pi]/2];
   (* Rescale to obtain the possible centers. *)
   v = ScalingTransform[{1, 1} Sqrt[1 - \[Gamma]^2]/\[Gamma]];
   x = v[u[t[#]]] & /@ {q1, q2};
   (* Back-transform the solutions. *)
   InverseFunction[Composition[t, s, r]] /@ x
   ];
Related Question