The problem of calculating the number $p_n$ of necklaces when reflections are included among the admissible symmetries is just as easy, as the equivalence classes are still of the same size $2n$, giving $$p_n = \frac{n!}{2n} = \frac{1}{2} (n-1)!.$$
To compute this with Polya counting we need the cycle index $Z(D_n)$ of the dihedral group $D_n$, which contains reflections and rotations. It is given by
$$Z(D_n) = \frac{1}{2} Z(C_n) +
\begin{cases}
\frac{1}{2} a_1 a_2^{(n-1)/2}, & n \mbox{ odd, } \\
\frac{1}{4}
\left( a_1^2 a_2^{(n-2)/2} + a_2^{n/2} \right), & n \mbox{ even.}
\end{cases}.$$
There is more information here.
The cycle index computation confirms the result of the basic analysis:
with(numtheory);
with(group):
with(combinat):
pet_cycleind_dihedral :=
proc(n)
local d, s, t;
s := 0;
for d in divisors(n) do
s := s + phi(d)*a[d]^(n/d);
od;
if type(n, odd) then
t := n*a[1]*a[2]^((n-1)/2);
else
t := n/2*(a[1]^2*a[2]^((n-2)/2)+a[2]^(n/2));
fi;
(s+t)/2/n;
end;
pet_varinto_cind :=
proc(poly, ind)
local subs1, subs2, polyvars, indvars, v, pot, res;
res := ind;
polyvars := indets(poly);
indvars := indets(ind);
for v in indvars do
pot := op(1, v);
subs1 :=
[seq(polyvars[k]=polyvars[k]^pot,
k=1..nops(polyvars))];
subs2 := [v=subs(subs1, poly)];
res := subs(subs2, res);
od;
res;
end;
v :=
proc(n)
option remember;
local p, k, gf;
p := add(cat(q, k), k=1..n);
gf := expand(pet_varinto_cind(p, pet_cycleind_dihedral(n)));
for k to n do
gf := coeff(gf, cat(q, k), 1);
od;
gf;
end;
The code in action looks like this:
> seq([n, v(n), (n-1)!/2], n=1..12);
[1, 1, 1/2], [2, 1, 1/2], [3, 1, 1], [4, 3, 3], [5, 12, 12], [6, 60, 60], [7, 360, 360],
[8, 2520, 2520], [9, 20160, 20160], [10, 181440, 181440], [11, 1814400, 1814400],
[12, 19958400, 19958400]
Remark July 4 2018. Let me observe once more that with all beads a distinct color all orbits are the same size namely $2n$, giving the answer $(n-1)!/2.$ Polya counting is not needed here because Burnside says that if we have $n$ different colors and a color is to be constant on the cycles we need a permutation that factors into at least $n$ cycles. There is only one of these namely the identity which has $n$ fixed points. The number of ways of assigning the $n$ colors to these fixed points is $n!$ and we once more obtain $n!/2/n.$ On the other hand the cycle index becomes useful when we seek to classify bracelets according to the distribution of colors where colors may be repeated. For example with three colors red green and blue and a bracelet of six beads we get
$$Z(D_6)(R+B+G) =
{B}^{6}+{B}^{5}G+{B}^{5}R+3\,{B}^{4}{G}^{2}+3\,{B}^{4}GR
\\ +3\,{B}^{4}{R}^{2}+3\,{B}^{3}{G}^{3}+6\,{B}^{3}{G}^{2}R
\\ +6\,{B}^{3}G{R}^{2}+3\,{B}^{3}{R}^{3}+3\,{B}^{2}{G}^{4}
\\ +6\,{B}^{2}{G}^{3}R+11\,{B}^{2}{G}^{2}{R}^{2}+6\,{B}^{2}G{R}^{3}
\\ +3\,{B}^{2}{R}^{4}+B{G}^{5}+3\,B{G}^{4}R+6\,B{G}^{3}{R}^{2}
\\ +6\,B{G}^{2}{R}^{3}+3\,BG{R}^{4}+B{R}^{5}+{G}^{6}+{G}^{5}R
\\ +3\,{G}^{4}{R}^{2}+3\,{G}^{3}{R}^{3}+3\,{G}^{2}{R}^{4}
\\ +G{R}^{5}+{R}^{6}.$$
This is where the Maple code may be deployed, using the command
pet_varinto_cind(R+G+B, pet_cycleind_dihedral(6));
The reader may want to verify some of these using pen and paper. For example the term $3B^4G^2$ represents the possibilities using four blue beads and two green ones which are: green beads adjacent, green beads with one blue bead and three blue beads separating them and green beads with two blue beads separating them.
The "ring" question asks "how many ways are there to put 6 people in a ring", where two "ways" are identical if each individual has the same left and right neighbours.
The "table" question asks "how many ways are there to put 6 people at a table", where two "ways" are identical if each individual has the same left and right neighbours and the same place at the table.
It is easy to see that since the possible rotations are 6, the answer to the first question will be 6 times the answer to the second question, and indeed 6! = 6 x 5!.
Concerning the "necklace" problem, the difference from the "ring" problem is that you cannot put people upside down without noticing - while you can to so with a necklace, obtaining a pattern which is symmetric. So the number of combination is halved, because two symmetric combinations are considered as one.
Best Answer
Clockwise and counterclockwise can be "indistinguishable" in the same way that rotations can be "indistinguishable".
If a necklace with ten different-colored beads were placed in a circular shape in front of you, I think you could see which colors of beads were closest to you. If you closed your eyes for a moment, and then someone rotated the necklace around its circle so that those beads were now furthest from you, I think you could tell that something had changed when you opened your eyes. Am I wrong about either of those statements?
When the authors of the book wrote the word "indistinguishable," they were not saying anything about your ability to detect when the necklace is rotated or reversed in direction. If the necklace has ten different beads, then of course you can tell when the necklace is rotated or flipped! What the authors meant by "indistinguishable" is merely that it is still the same necklace, and does not become a new arrangement of beads on a necklace every time you move it.
Another way to look at it is that if I make a necklace by stringing all the beads in a clockwise order, and then I make another necklace by taking the beads in the same sequence of colors but this time I string them in counterclockwise order, the two necklaces I have just made are considered identical. We do not care which way I went around the circle when I strung the beads, because we can always flip the necklace over and now it looks just like it would if I had strung it in the other direction. That is the sense in which the clockwise and counterclockwise sequences are "indistinguishable."