Expressing Hermite polynomials using confluent hypergeometric functions

Question

On Wikipedia it's said that one could express the Hermite polynomials using the $_1F_1$ function and the following formulae are provided:

$$H_{2n}(x)=(-1)^n \frac{(2n)!}{n!}(_1F_1)(-n,1/2;x^2),$$

$$H_{2n+1}(x)=(-1)^n \frac{(2n+1)!}{n!}2(_1F_1)(-n,3/2;x^2),$$

Even though I've made quite an extensive search online I haven't been able to find some detailed proof of the latter.

If you have some idea on how to prove it, or you know some source where an explanation is given I would be thankful.
Thanks in advance!

Answer 1

The equations you have provided are equivalent to the Wikipedia ones, when a slight typo is fixed. $$H_{2n}(x)=(-1)^n \frac{(2n)!}{n!}(_1F_1)(-n,1/2;x^2), \tag{1} $$ $$H_{2n+1}(x)=(-1)^n \frac{(2n+1)!}{n!}2x(_1F_1)(-n,3/2,x^2). \tag{2}$$ Notice the $\,2x\,$ instead of $\,2\,$ in equation $(2)$ which is the fix. I used the Wolfram language code

ClearAll[HypergeometricPFQk, WHnk1, WHnk2, Hnk, x];
(* General terms of a Hypergeometric sum *)
HypergeometricPFQk[a_List, b_List, z_, k_] := 
   z^k/k! Product[Pochhammer[ai, k], {ai, a}]/
          Product[Pochhammer[bi, k], {bi, b}];
(* General term of Wikipedia article single case *)
WHnk1[n_, k_, x_: x] := n! (-1)^k /k!/(n - 2 k)! (2 x)^(n - 2 k);
(* General term of Wikipedia article even/odd case *)
WHnk2[m_, k_, x_: x] := With[{n = Quotient[m, 2], b = Mod[m, 2]},
    m! (-1)^(n-k)/(2 k + b)!/(n - k)! (2 x)^(2 k + b)];
(* Fixed Equations (1) and (2) using Hypergeometric1F1 *)
Hnk[m_, k_, x_: x] := With[{n = Quotient[m, 2], b = Mod[m, 2]},
(-1)^n m!/n! HypergeometricPFQk[{-n}, {b + 1/2}, x^2, k] x^b (b + 1)];
(* Table of results *)
Table[ {n, HermiteH[n, x] == Total@Table[Hnk[n, k], {k, 0, n/2}],
   Table[WHnk1[n, k], {k, 0, n/2}], Table[WHnk2[n, k], {k, 0, n/2}],
   Table[Hnk[n, k], {k, 0, n/2}]}, {n, 0, 4}] // InputForm

which evaluates to

{{0, True, {1}, {1}, {1}},
 {1, True, {2*x}, {2*x}, {2*x}},
 {2, True, {4*x^2, -2}, {-2, 4*x^2}, {-2, 4*x^2}},
 {3, True, {8*x^3, -12*x}, {-12*x, 8*x^3}, {-12*x, 8*x^3}}, 
 {4, True, {16*x^4, -48*x^2, 12}, {12, -48*x^2, 16*x^4}, {12, -48*x^2, 16*x^4}}}

They give the same results except the Wikipedia single case sum gives the terms in reverse order.