[Tex/LaTex] Emacs gives me “Latex: problems after [0] pages”

auctexemacs

Yesterday, out of the blue, my emacs+auctex configuration stopped working and I started getting the following error when trying to do pdflatex, "Latex: problems after [0] pages".

Hitting Ctrl+C+L I see

Running `LaTeX' on `final' with ``pdflatex -synctex=1 -file-line-error %(extraopts) --synctex=1 -interaction=nonstopmode "\input" /home/mdn/research/final.tex''
/bin/sh: -c: line 0: syntax error near unexpected token `('
/bin/sh: -c: line 0: `pdflatex -synctex=1 -file-line-error %(extraopts) --synctex=1 -interaction=nonstopmode "\input" /home/mdn/research/final.tex'

I have not been able to figure out a solution. Actually, after updating my system (to Fedora 21) my emacs has started to act a bit weirdly, with several minor glitches. If anybody could share a working, minimal, synctex-enabled .emacs file I'd greatly appreciate it.

Best Answer

I would search your init files for references to TeX-expand-list. It's possible you're removing the value, though it seems unlikely.

Next, try updating AUCTeX (M-x list-packages) and restarting Emacs. Might be that simple.

If all else fails, try sticking this in your .emacs:

(add-to-list
 'TeX-expand-list
 (list "%(extraopts)"
       (lambda nil TeX-command-extra-options)))

This makes the extraopts key available to TeX-expand-command.

Related Solutions

[Tex/LaTex] Setup SyncTeX with Emacs

I combined some of the links mentioned here, you will find the links in the source comments. This code supports:

Forward search (Emacs to Evince, via C-c C-v)
Backward/Inverse search (Evince to Emacs, via C-Mouse-1, that is Ctrl + "Left Click" in Evince)
Path names with spaces
Multifile setups (TeX files requested by Evince will be opened if they aren't open yet)

; SyncTeX basics

; un-urlify and urlify-escape-only should be improved to handle all special characters, not only spaces.
; The fix for spaces is based on the first comment on http://emacswiki.org/emacs/AUCTeX#toc20

(defun un-urlify (fname-or-url)
  "Transform file:///absolute/path from Gnome into /absolute/path with very limited support for special characters"
  (if (string= (substring fname-or-url 0 8) "file:///")
      (url-unhex-string (substring fname-or-url 7))
    fname-or-url))

(defun urlify-escape-only (path)
  "Handle special characters for urlify"
  (replace-regexp-in-string " " "%20" path))

(defun urlify (absolute-path)
  "Transform /absolute/path to file:///absolute/path for Gnome with very limited support for special characters"
  (if (string= (substring absolute-path 0 1) "/")
      (concat "file://" (urlify-escape-only absolute-path))
      absolute-path))


; SyncTeX backward search - based on http://emacswiki.org/emacs/AUCTeX#toc20, reproduced on https://tex.stackexchange.com/a/49840/21017

(defun th-evince-sync (file linecol &rest ignored)
  (let* ((fname (un-urlify file))
         (buf (find-file fname))
         (line (car linecol))
         (col (cadr linecol)))
    (if (null buf)
        (message "[Synctex]: Could not open %s" fname)
      (switch-to-buffer buf)
      (goto-line (car linecol))
      (unless (= col -1)
        (move-to-column col)))))

(defvar *dbus-evince-signal* nil)

(defun enable-evince-sync ()
  (require 'dbus)
  ; cl is required for setf, taken from: http://lists.gnu.org/archive/html/emacs-orgmode/2009-11/msg01049.html
  (require 'cl)
  (when (and
         (eq window-system 'x)
         (fboundp 'dbus-register-signal))
    (unless *dbus-evince-signal*
      (setf *dbus-evince-signal*
            (dbus-register-signal
             :session nil "/org/gnome/evince/Window/0"
             "org.gnome.evince.Window" "SyncSource"
             'th-evince-sync)))))

(add-hook 'LaTeX-mode-hook 'enable-evince-sync)


; SyncTeX forward search - based on https://tex.stackexchange.com/a/46157

;; universal time, need by evince
(defun utime ()
  (let ((high (nth 0 (current-time)))
        (low (nth 1 (current-time))))
   (+ (* high (lsh 1 16) ) low)))

;; Forward search.
;; Adapted from http://dud.inf.tu-dresden.de/~ben/evince_synctex.tar.gz
(defun auctex-evince-forward-sync (pdffile texfile line)
  (let ((dbus-name
     (dbus-call-method :session
               "org.gnome.evince.Daemon"  ; service
               "/org/gnome/evince/Daemon" ; path
               "org.gnome.evince.Daemon"  ; interface
               "FindDocument"
               (urlify pdffile)
               t     ; Open a new window if the file is not opened.
               )))
    (dbus-call-method :session
          dbus-name
          "/org/gnome/evince/Window/0"
          "org.gnome.evince.Window"
          "SyncView"
          (urlify-escape-only texfile)
          (list :struct :int32 line :int32 1)
  (utime))))

(defun auctex-evince-view ()
  (let ((pdf (file-truename (concat default-directory
                    (TeX-master-file (TeX-output-extension)))))
    (tex (buffer-file-name))
    (line (line-number-at-pos)))
    (auctex-evince-forward-sync pdf tex line)))

;; New view entry: Evince via D-bus.
(setq TeX-view-program-list '())
(add-to-list 'TeX-view-program-list
         '("EvinceDbus" auctex-evince-view))

;; Prepend Evince via D-bus to program selection list
;; overriding other settings for PDF viewing.
(setq TeX-view-program-selection '())
(add-to-list 'TeX-view-program-selection
         '(output-pdf "EvinceDbus"))

This will likely break for:

Path names with special characters other than spaces

I used these helpful links:

https://tex.stackexchange.com/a/46157 (forward search)
http://emacswiki.org/emacs/AUCTeX#toc20 (backward search, space handling)
http://lists.gnu.org/archive/html/emacs-orgmode/2009-11/msg01049.html (fix for missing setf)

I tested with

Emacs 24.2
Evince 3.4.0
OpenSUSE 12.2

[Tex/LaTex] AUCTeX can’t find PDFLaTeX

AUCTeX complains that pdflatex cannot be found. However, according to your comments you checked and found pdftex, not pdflatex, which still can be missing.

Today, pdflatex if often just a symbolic link to pdftex. For example, on my Ubuntu system with TeX Live 2011:

> ls -l `which pdflatex`
lrwxrwxrwx 1 root root 49 2011-10-07 22:13 /usr/local/bin/pdflatex
    -> /usr/local/texlive/2011/bin/x86_64-linux/pdflatex
> ls -l /usr/local/texlive/2011/bin/x86_64-linux/pdflatex
lrwxrwxrwx 1 root root 6 2009-08-15 19:49
    /usr/local/texlive/2011/bin/x86_64-linux/pdflatex -> pdftex

It finally points to pdftex.

So, you could

configure Emacs/AUCTeX to run pdftex instead of pdflatex, since LaTeX is just the format, not the engine or executable
or create a symbolic link, such as by
```
ln -s /usr/local/texlive/2011/bin/x86_64-linux/pdftex pdflatex
```
in your path, where it can be found.
or use the TeX Live Manager, start it by
```
sudo tlmgr -gui
```
and have a look in the menu Actions/ Managing symbolic links to the point update symbolic links or let it create symbolic links, this is also possible via command line option to tlmgr (see tlmgr --help).

Best Answer

Related Solutions

[Tex/LaTex] Setup SyncTeX with Emacs

[Tex/LaTex] AUCTeX can’t find PDFLaTeX

Related Question